discord-bot-game/Bot/HackerBattle.fs

module Degenz.HackerBattle

open System
open System.Threading.Tasks
open DSharpPlus
open DSharpPlus.Entities
open DSharpPlus.EventArgs
open DSharpPlus.SlashCommands
open Degenz
open Degenz.Shared
open Degenz.Store

let getTimeTillCooldownFinishes (timespan : TimeSpan) timestamp =
    let timeRemaining = timespan - (DateTime.UtcNow - timestamp)
    if timeRemaining.Hours > 0 then
        $"{timeRemaining.Hours} hours"
    elif timeRemaining.Minutes > 0 then
        $"{timeRemaining.Minutes} minutes"
    else
        $"{timeRemaining.Seconds} seconds"


let checkIfPlayerIsAttackingThemselves defender attacker  =
    match attacker.DiscordId = defender.DiscordId with
    | true -> Error "You think you're clever? You can't hack yourself, pal."
    | false -> Ok attacker

let checkForExistingHack defenderId attacker =
    attacker.Actions
    |> removeExpiredActions
    |> getAttacksFlat
    |> Array.tryFind (fun (_,t,_) -> t.Id = defenderId)
    |> function
       | Some ( atk , target , _ ) ->
           let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromHours(24)) atk.Timestamp
           Error $"You can only hack the same target once every 24 hours, wait {cooldown} to attempt another hack on {target.Name}."
       | None ->
           Ok attacker

let checkIfHackHasCooldown hackId attacker =
    let mostRecentHackAttack =
        attacker.Actions
        |> Array.tryFind (fun a -> a.ActionId = hackId)
        |> function
           | Some a -> a.Timestamp
           | None -> DateTime.MinValue;
    if DateTime.UtcNow - mostRecentHackAttack > TimeSpan.FromMinutes(5) then
        Ok attacker
    else
       let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromMinutes(5)) mostRecentHackAttack
       let item = armoury |> Array.find (fun i -> i.Id = hackId)
       Error $"{item.Name} is currently on cooldown, wait {cooldown} to use it again."

let checkIfInventoryIsEmpty attacker =
    match attacker.Arsenal with
    | [||] -> Error $"You currently do not have any Hacks to use against others. Please go to the store and purchase one."
    | _ -> Ok attacker

let calculateDamage (hack : BattleItem) (shield : BattleItem) =
    if hack.Class = shield.Class
        then Strong
        else Weak

let runHackerBattle defender hack =
    Player.defenses defender
    |> removeExpiredActions
    |> Array.map (fun dfn -> armoury |> Array.find (fun w -> w.Id = dfn.ActionId))
    |> Array.map (calculateDamage (hack))
    |> Array.contains Weak

let updateCombatants attacker defender hack prize =
    let updatePlayer amount attack p =
       { p with Actions = Array.append [| attack |] p.Actions ; Bank = max (p.Bank + amount) 0<GBT> }
    let target = { Id = defender.DiscordId ; Name = defender.Name }
    let attack = { ActionId = int hack ; Type = Attack { Target = target ; Result = prize > 0<GBT> } ; Timestamp = DateTime.UtcNow }

    [ DbService.updatePlayer <| updatePlayer prize attack attacker
      DbService.updatePlayer <| modifyPlayerBank defender -prize ]
    |> Async.Parallel
    |> Async.Ignore

let successfulHack (event : ComponentInteractionCreateEventArgs) attacker defender hack =
    async {
        let prize = 3<GBT>

        do! updateCombatants attacker defender hack prize

        let embed = Embeds.responseSuccessfulHack defender.Name hack prize
        do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, embed)
            |> Async.AwaitTask

        let builder = Embeds.eventSuccessfulHack event defender.DiscordId prize
        let channel = event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle)
        do! channel.SendMessageAsync(builder)
            |> Async.AwaitTask
            |> Async.Ignore
    }

let failedHack (event : ComponentInteractionCreateEventArgs) attacker defender hack =
    async {
        let builder = DiscordInteractionResponseBuilder()
        let prize = 2<GBT>
        builder.IsEphemeral <- true
        builder.Content <- $"Hack failed! {defender.Name} was able to mount a successful defense! You lost {prize} GoodBoyTokenz!"
        do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
            |> Async.AwaitTask

        do! updateCombatants attacker defender hack -prize

        let builder = DiscordMessageBuilder()
        builder.WithContent($"Hacking attempt failed! <@{defender.DiscordId}> defended hack from {event.User.Username} and took {prize} from them! ") |> ignore
        let channel = (event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle))
        do! channel.SendMessageAsync(builder)
            |> Async.AwaitTask
            |> Async.Ignore
    }

let attack (ctx : InteractionContext) (target : DiscordUser) =
    async {
        let! attacker = DbService.tryFindPlayer ctx.Member.Id
        let! defender = DbService.tryFindPlayer target.Id
        match attacker , defender with
        | Some attacker , Some defender ->
            let hackAttempt =
                checkForExistingHack defender.DiscordId attacker
                |> Result.bind checkIfInventoryIsEmpty
                |> Result.bind (checkIfPlayerIsAttackingThemselves defender)
            match hackAttempt with
            | Ok _ ->
                let embed = Embeds.pickHack "Attack" attacker defender
                do! ctx.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, embed)
                    |> Async.AwaitTask
            | Error msg ->
                let builder =
                    DiscordInteractionResponseBuilder()
                        .WithContent(msg)
                        .AsEphemeral(true)
                do! ctx.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
        | None , _ -> do! notYetAHackerMsg ctx
        | _ , None -> do! createSimpleResponseAsync "Your target is not connected to the network, they must join first by using the /redpill command" ctx
    } |> Async.StartAsTask
    :> Task

let handleAttack (event : ComponentInteractionCreateEventArgs) =
    async {
        let split = event.Id.Split("-")
        let hack = enum<HackId>(int split.[1])
        let ( resultId , targetId ) = UInt64.TryParse split.[2]
        let! resultPlayer = DbService.tryFindPlayer event.User.Id
        let! resultTarget = DbService.tryFindPlayer targetId

        match resultPlayer , resultTarget , true , resultId with
        | Some attacker , Some defender , true , true ->
            do! checkForExistingHack defender.DiscordId attacker
                |> Result.bind (checkIfHackHasCooldown (int hack))
                |> function
                   | Ok _ ->
                       runHackerBattle defender (getItemFromArmoury <| int hack)
                       |> function
                          | false -> successfulHack event attacker defender hack
                          | true -> failedHack event attacker defender hack
                   | Error msg ->
                       let builder =
                           DiscordInteractionResponseBuilder()
                               .WithContent(msg)
                               .AsEphemeral(true)
                       event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                       |> Async.AwaitTask
        | _ ->
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- "Error occurred processing attack"
            do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
    }

let defend (ctx : InteractionContext) =
    async {
        let! player = DbService.tryFindPlayer ctx.Member.Id
        match player with
        | Some player ->
            if Player.shields player |> Array.length > 0 then
                let embed = Embeds.pickDefense "Defend" player
                do! ctx.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, embed)
                    |> Async.AwaitTask
            else
                let builder = DiscordInteractionResponseBuilder()
                builder.Content <- $"You currently do not have any Shields to protect your system. Please go to the armoury and purchase one."
                builder.AsEphemeral true |> ignore
                do! ctx.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
        | None -> do! notYetAHackerMsg ctx
    } |> Async.StartAsTask
    :> Task

let handleDefense (event : ComponentInteractionCreateEventArgs) =
    async {
        let split = event.Id.Split("-")
        let shield = enum<ShieldId>(int split.[1])
        let! playerResult = DbService.tryFindPlayer event.User.Id
        match playerResult with
        | Some player ->
            let updatedDefenses = Player.defenses player |> removeExpiredActions
            let alreadyUsedShield = updatedDefenses |> Array.exists (fun d -> d.ActionId = int shield)

            match alreadyUsedShield , updatedDefenses.Length < 2 with
            | false , true ->
                let embed = Embeds.responseCreatedShield shield
                do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, embed)
                    |> Async.AwaitTask
                let defense = { ActionId = int shield ; Type = Defense ; Timestamp = DateTime.UtcNow }
                do! DbService.updatePlayer <| { player with Actions = Array.append [| defense |] player.Actions  }
                let builder = DiscordMessageBuilder()
                builder.WithContent($"{event.User.Username} has protected their system!") |> ignore
                let channel = event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle)
                do! channel.SendMessageAsync(builder)
                    |> Async.AwaitTask
                    |> Async.Ignore
            | _ , false ->
                let builder = DiscordInteractionResponseBuilder()
                builder.IsEphemeral <- true
                let timestamp = updatedDefenses |> Array.rev |> Array.head |> fun a -> a.Timestamp // This should be the next expiring timestamp
                let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromHours(6)) timestamp
                builder.Content <- $"You are only allowed two shields at a time. Wait {cooldown} minutes to add another shield"
                do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
                do! DbService.updatePlayer <| { player with Actions = updatedDefenses }
            | true , _ ->
                let builder = DiscordInteractionResponseBuilder()
                builder.IsEphemeral <- true
                let timestamp = updatedDefenses |> Array.find (fun d -> d.ActionId = int shield) |> fun a -> a.Timestamp
                let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromHours(6)) timestamp
                builder.Content <- $"{shield} shield is already in use. Wait {cooldown} minutes to use this shield again"
                do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
                do! DbService.updatePlayer <| { player with Actions = updatedDefenses }

        | _ ->
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- "Error parsing Button Id"
            do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
    }

let handleButtonEvent (_ : DiscordClient) (event : ComponentInteractionCreateEventArgs) =
    let task =
        match event.Id with
        | id when id.StartsWith("Attack")  -> handleAttack event
        | id when id.StartsWith("Defend")  -> handleDefense event
        | id when id.StartsWith("Trainer") -> Trainer.handleButtonEvent event
        | _ ->
            async {
                let builder = DiscordInteractionResponseBuilder()
                builder.IsEphemeral <- true
                builder.Content <- $"Incorrect Action identifier {event.Id}"
                do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                    |> Async.AwaitTask
            }
    async {
        return! task
    } |> Async.StartAsTask
    :> Task

type HackerGame() =
    inherit ApplicationCommandModule ()

    [<SlashCommand("hack", "Send a hack attack to another player")>]
    member this.AttackCommand (ctx : InteractionContext, [<Option("target", "The player you want to hack")>] target : DiscordUser) =
        if ctx.Channel.Id = GuildEnvironment.channelTraining then
            Trainer.attack ctx target
        else
            attack ctx target

    [<SlashCommand("defend", "Create a passive defense that will last 24 hours")>]
    member this.DefendCommand (ctx : InteractionContext) =
        if ctx.Channel.Id = GuildEnvironment.channelTraining then
            Trainer.defend ctx
        else
            defend ctx

//    [<SlashCommand("test-autocomplete", "Create a passive defense that will last 24 hours")>]
    member this.TestAutoComplete (ctx : InteractionContext) =
        async {
            let builder = DiscordInteractionResponseBuilder()
//            builder.WithContent("Not working")
            builder.IsEphemeral <- true
            do! ctx.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                |> Async.AwaitTask
        } |> Async.StartAsTask
          :> Task