discord-bot-game/Bot/Game.fs

namespace Degenz

open System.Threading.Tasks
open DSharpPlus
open DSharpPlus.Entities
open DSharpPlus.EventArgs
open DSharpPlus.SlashCommands
open Degenz.DbService
open Degenz.Messaging

module Game =
    let HackPrize = 10<GBT>
    let ShieldPrize = 5<GBT>

    let SameTargetAttackCooldown = System.TimeSpan.FromHours(6)

    let getClassButtonColor = function
        | Network -> ButtonStyle.Danger
        | Exploit -> ButtonStyle.Success
        | Penetration -> ButtonStyle.Primary

    let getClassEmbedColor = function
        | Network -> DiscordColor.Red
        | Penetration -> DiscordColor.Blurple
        | Exploit -> DiscordColor.Green

    let getGoodAgainst = function
        | BattleClass.Network     -> ( ShieldId.Firewall   , HackId.Virus        )
        | BattleClass.Penetration -> ( ShieldId.Cypher     , HackId.RemoteAccess )
        | BattleClass.Exploit     -> ( ShieldId.Encryption , HackId.Worm         )

    let executePlayerAction (ctx : IDiscordContext) (dispatch : PlayerData -> Async<unit>) =
        async {
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- "Content"
            do! ctx.Respond InteractionResponseType.DeferredChannelMessageWithSource builder |> Async.AwaitTask
            let! playerResult = tryFindPlayer (ctx.GetDiscordMember().Id)
            match playerResult with
            | Some player -> do! dispatch player
            | None -> do! Messaging.sendFollowUpMessage ctx "You are currently not a hacker, first use the /redpill command to become one"
        } |> Async.StartAsTask :> Task

    let executePlayerActionWithTarget (targetPlayer : DiscordUser) (ctx : IDiscordContext) (dispatch : PlayerData -> PlayerData -> Async<unit>) =
        async {
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- "Content"
            do! ctx.Respond InteractionResponseType.DeferredChannelMessageWithSource builder |> Async.AwaitTask
            let! players =
                [ tryFindPlayer (ctx.GetDiscordMember().Id)
                  tryFindPlayer targetPlayer.Id ]
                |> Async.Parallel
            match players.[0] , players.[1] with
            | Some player , Some target -> do! dispatch player target
            | None , _ -> do! Messaging.sendFollowUpMessage ctx "You are currently not a hacker, first use the /redpill command to become one"
            | _ , None ->
                if targetPlayer.IsBot
                    then do! Messaging.sendFollowUpMessage ctx $"{targetPlayer.Username} is a bot, pick a real human to hack"
                    else do! Messaging.sendFollowUpMessage ctx "Your target is not connected to the network, they must join first by using the /redpill command"
        } |> Async.StartAsTask :> Task

    let executePlayerActionWithTargetId defer (targetId : uint64) (ctx : IDiscordContext) (dispatch : PlayerData -> PlayerData -> Async<unit>) =
        async {
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- "Content"
            if defer then
                do! ctx.Respond InteractionResponseType.DeferredChannelMessageWithSource builder |> Async.AwaitTask
            let! players =
                [ tryFindPlayer (ctx.GetDiscordMember().Id)
                  tryFindPlayer targetId ]
                |> Async.Parallel
            match players.[0] , players.[1] with
            | Some player , Some target -> do! dispatch player target
            | None , _ -> do! Messaging.sendFollowUpMessage ctx "You are currently not a hacker, first use the /redpill command to become one"
            | _ , None -> do! Messaging.sendFollowUpMessage ctx "Your target is not connected to the network, they must join first by using the /redpill command"
        } |> Async.StartAsTask :> Task

module Player =
    let getItems itemType (player : PlayerData) = player.Arsenal |> Array.filter (fun i -> i.Type = itemType)
    let getHacks (player : PlayerData) = getItems ItemType.Hack player
    let getShields (player : PlayerData) = getItems ItemType.Shield player
    let getAttacks player =
        player.Actions
        |> Array.filter (fun act -> match act.Type with Attack _ -> true | _ -> false || act.ActionId < 12)
    let getDefenses player =
        player.Actions
        |> Array.filter (fun act -> match act.Type with Defense -> true | _ -> false || act.ActionId < 12)

    // TODO: This parameter is a result of putting the cooldown on the attack side. Put the cooldown on the defender
    // side and only check if it's the same target, we need to refactor Actions
    let removeExpiredActions filterByAttackCooldown player =
        let actions =
            player.Actions
            |> Array.filter (fun (act : Action) ->
                let itemCooldown =
                    if act.ActionId < 12 then
                        (Armory.getItem act.ActionId).Cooldown
                    else
                        match act.Type with
                        | Attack _ -> 1<mins>
                        | Defense -> 720<mins>
                    |> int

                match act.Type , filterByAttackCooldown with
                | Attack _ , true  -> System.DateTime.UtcNow - act.Timestamp < System.TimeSpan.FromMinutes(itemCooldown)
                | Attack _ , false -> System.DateTime.UtcNow - act.Timestamp < Game.SameTargetAttackCooldown
                | Defense , _      -> System.DateTime.UtcNow - act.Timestamp < System.TimeSpan.FromMinutes(itemCooldown))
        { player with Actions = actions }

    let modifyBank (player : PlayerData) amount = { player with Bank = max (player.Bank + amount) 0<GBT> }

    let getAttacksFlat actions = actions |> Array.choose (fun act -> match act.Type with Attack ar -> Some (act,ar.Target,ar.Result) | Defense -> None)

module Arsenal =
    let battleItemFormat (items : BattleItem array) =
        match items with
        | [||] -> "None"
        | _ -> items |> Array.toList |> List.map (fun i -> i.Name) |> String.concat ", "

    let actionFormat (actions : Action array) =
        match actions with
        | [||] -> "None"
        | _ ->
            let hacks , defenses =
                actions
                |> Array.filter (fun act -> act.ActionId < 12)
                |> Array.partition (fun act -> match act.Type with Attack _ -> true | Defense -> false)
            let hacks = hacks |> Array.take (min hacks.Length 10)
            hacks
            |> Array.append defenses
            |> Array.map (fun act ->
                let item = Armory.getItem act.ActionId
                match act.Type with
                | Attack atk ->
                    let cooldown = Messaging.getTimeText false Game.SameTargetAttackCooldown act.Timestamp
                    $"Hacked {atk.Target.Name} {cooldown} ago"
                | Defense ->
                    let cooldown = Messaging.getTimeText true (System.TimeSpan.FromMinutes(int item.Cooldown)) act.Timestamp
                    $"{item.Name} Shield active for {cooldown}")
            |> String.concat "\n"

    let statusFormat p =
        $"**Hacks:** {Player.getHacks p |> battleItemFormat}\n
    **Shields:** {Player.getShields p |> battleItemFormat}\n
    **Hack Attacks:**\n{Player.getAttacks p |> actionFormat}\n
    **Active Shields:**\n{Player.getDefenses p |> actionFormat}"