discord-bot-game/Bot/HackerBattle.fs

module Degenz.HackerBattle

open System
open System.Threading.Tasks
open DSharpPlus
open DSharpPlus.Entities
open DSharpPlus.EventArgs
open DSharpPlus.SlashCommands
open Degenz
open Degenz.Messaging

let (>>=) x f = Result.bind f x

let checkIfPlayerIsAttackingThemselves defender attacker  =
    match attacker.DiscordId = defender.DiscordId with
    | true -> Error "You think you're clever? You can't hack yourself, pal."
    | false -> Ok attacker

let checkForExistingTarget defenderId attacker =
    attacker.Actions
    |> Player.getAttacksFlat
    |> Array.tryFind (fun (_,t,_) -> t.Id = defenderId)
    |> function
       | Some ( atk , target , _ ) ->
           let cooldown = getTimeTillCooldownFinishes Player.SameTargetAttackCooldown atk.Timestamp
           Error $"You can only hack the same target once every {Player.SameTargetAttackCooldown.Hours} hours, wait {cooldown} to attempt another hack on {target.Name}."
       | None -> Ok attacker

let checkIfHackHasCooldown hackId attacker =
    let mostRecentHackAttack =
        attacker.Actions
        |> Array.tryFind (fun a -> a.ActionId = hackId)
        |> function
           | Some a -> a.Timestamp
           | None -> DateTime.MinValue
    let item = Armory.getItem hackId
    if DateTime.UtcNow - mostRecentHackAttack > TimeSpan.FromMinutes(int item.Cooldown) then
        Ok attacker
    else
       let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromMinutes(int item.Cooldown)) mostRecentHackAttack
       let item = Armory.battleItems |> Array.find (fun i -> i.Id = hackId)
       Error $"{item.Name} is currently on cooldown, wait {cooldown} to use it again."

let checkIfInventoryIsEmpty attacker =
    match attacker.Arsenal with
    | [||] -> Error $"You currently do not have any Hacks to steal 💰$GBT from others. Please go to the <#{GuildEnvironment.channelArmory}> and purchase one."
    | _ -> Ok attacker

let checkIfTargetHasMoney (target : PlayerData) attacker =
    if target.Bank < Game.HackPrize
        then Error $"{target.Name} does not have enough 💰$GBT to steal from, the broke loser. Pick a different target."
        else Ok attacker

let calculateDamage (hack : BattleItem) (shield : BattleItem) =
    if hack.Class = shield.Class
        then Strong
        else Weak

let runHackerBattle defender hack =
    defender
    |> Player.removeExpiredActions
    |> Player.defenses
    |> Array.map (fun dfn -> Armory.battleItems |> Array.find (fun w -> w.Id = dfn.ActionId))
    |> Array.map (calculateDamage (hack))
    |> Array.contains Weak

let updateCombatants attacker defender hack prize =
    let updatePlayer amount attack p =
       { p with Actions = Array.append [| attack |] p.Actions ; Bank = max (p.Bank + amount) 0<GBT> }
    let target = { Id = defender.DiscordId ; Name = defender.Name }
    let attack = { ActionId = int hack ; Type = Attack { Target = target ; Result = prize > 0<GBT> } ; Timestamp = DateTime.UtcNow }

    [ DbService.updatePlayer <| updatePlayer prize attack attacker
      DbService.updatePlayer <| Player.modifyBank defender -prize ]
    |> Async.Parallel
    |> Async.Ignore

let successfulHack (event : ComponentInteractionCreateEventArgs) attacker defender hack =
    async {
        do! updateCombatants attacker defender hack Game.HackPrize

        let embed = Embeds.responseSuccessfulHack (Armory.getItem (int hack))
        do! event.Interaction.CreateFollowupMessageAsync(embed)
            |> Async.AwaitTask
            |> Async.Ignore

        let builder = Embeds.eventSuccessfulHack event defender.DiscordId Game.HackPrize
        let channel = event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle)
        do! channel.SendMessageAsync(builder)
            |> Async.AwaitTask
            |> Async.Ignore
    }

let failedHack (event : ComponentInteractionCreateEventArgs) attacker defender hack =
    async {
        let builder = DiscordInteractionResponseBuilder()
        builder.IsEphemeral <- true
        builder.Content <- $"Hack failed! {defender.Name} was able to mount a successful defense! You lost {Game.ShieldPrize} GoodBoyTokenz!"
        do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
            |> Async.AwaitTask

        do! updateCombatants attacker defender hack -Game.ShieldPrize

        let builder = DiscordMessageBuilder()
        builder.WithContent($"Hacking attempt failed! <@{defender.DiscordId}> defended hack from {event.User.Username} and took {Game.ShieldPrize} from them! ") |> ignore
        let channel = (event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle))
        do! channel.SendMessageAsync(builder)
            |> Async.AwaitTask
            |> Async.Ignore
    }

let attack (ctx : InteractionContext) (target : DiscordUser) =
    Game.executePlayerInteraction ctx (fun attacker -> async {
        let! defender = DbService.tryFindPlayer target.Id
        match defender with
        | Some defender ->
          do! attacker
              |> Player.removeExpiredActions
              |> checkForExistingTarget defender.DiscordId
              >>= checkIfInventoryIsEmpty
              >>= checkIfTargetHasMoney defender
              >>= checkIfPlayerIsAttackingThemselves defender
              |> function
                 | Ok _ ->
                     let embed = Embeds.pickHack "Attack" attacker defender
                     ctx.FollowUpAsync(embed)
                     |> Async.AwaitTask
                     |> Async.Ignore
                 | Error msg ->
                     let builder =
                         DiscordFollowupMessageBuilder()
                             .WithContent(msg)
                             .AsEphemeral(true)
                     ctx.FollowUpAsync(builder)
                     |> Async.AwaitTask
                     |> Async.Ignore
        | None -> do! sendSimpleResponse ctx "Your target is not connected to the network, they must join first by using the /redpill command"
    })

let handleAttack (event : ComponentInteractionCreateEventArgs) =
    Game.executePlayerEvent event (fun attacker -> async {
        let split = event.Id.Split("-")
        let hack = enum<HackId>(int split.[1])
        let ( resultId , targetId ) = UInt64.TryParse split.[2]
        let! resultTarget = DbService.tryFindPlayer targetId

        match resultTarget , true , resultId with
        | Some defender , true , true ->
            do! attacker
                |> Player.removeExpiredActions
                |> checkForExistingTarget defender.DiscordId
                >>= (checkIfHackHasCooldown (int hack))
                |> function
                   | Ok _ ->
                       runHackerBattle defender (Armory.getItem (int hack))
                       |> function
                          | false -> successfulHack event attacker defender hack
                          | true -> failedHack event attacker defender hack
                   | Error msg -> Messaging.sendFollowUpMessage event msg
        | _ -> do! Messaging.sendFollowUpMessage event "Error occurred processing attack"
    })

let defend (ctx : InteractionContext) =
    Game.executePlayerInteraction ctx (fun player -> async {
        if Player.shields player |> Array.length > 0 then
            let embed = Embeds.pickDefense "Defend" player
            do! ctx.FollowUpAsync(embed)
                |> Async.AwaitTask
                |> Async.Ignore
        else
            let msg = $"You currently do not have any Shields to protect you. Please go to the <#{GuildEnvironment.channelArmory}> and purchase one."
            do! Messaging.sendFollowUpMessageFromCtx ctx msg
    })

let handleDefense (event : ComponentInteractionCreateEventArgs) =
    Game.executePlayerEvent event (fun player -> async {
        let split = event.Id.Split("-")
        let shieldId = enum<ShieldId>(int split.[1])
        let updatedDefenses = player |> Player.removeExpiredActions |> Player.defenses
        let alreadyUsedShield = updatedDefenses |> Array.exists (fun d -> d.ActionId = int shieldId)

        match alreadyUsedShield , updatedDefenses.Length < 2 with
        | false , true ->
            let embed = Embeds.responseCreatedShield (Armory.getItem (int shieldId))
            do! event.Interaction.CreateFollowupMessageAsync(embed)
                |> Async.AwaitTask
                |> Async.Ignore
            let defense = { ActionId = int shieldId ; Type = Defense ; Timestamp = DateTime.UtcNow }
            do! DbService.updatePlayer <| { player with Actions = Array.append [| defense |] player.Actions  }
            let builder = DiscordMessageBuilder()
            builder.WithContent($"{event.User.Username} has protected their system!") |> ignore
            let channel = event.Guild.GetChannel(GuildEnvironment.channelEventsHackerBattle)
            do! channel.SendMessageAsync(builder)
                |> Async.AwaitTask
                |> Async.Ignore
        | _ , false ->
            let builder = DiscordFollowupMessageBuilder()
            builder.IsEphemeral <- true
            let timestamp = updatedDefenses |> Array.rev |> Array.head |> fun a -> a.Timestamp // This should be the next expiring timestamp
            let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromHours(6)) timestamp
            builder.Content <- $"You are only allowed two shields at a time. Wait {cooldown} minutes to add another shield"
            do! event.Interaction.CreateFollowupMessageAsync(builder)
                |> Async.AwaitTask
                |> Async.Ignore
            do! DbService.updatePlayer <| { player with Actions = updatedDefenses }
        | true , _ ->
            let builder = DiscordFollowupMessageBuilder()
            builder.IsEphemeral <- true
            let timestamp = updatedDefenses |> Array.find (fun d -> d.ActionId = int shieldId) |> fun a -> a.Timestamp
            let cooldown = getTimeTillCooldownFinishes (TimeSpan.FromHours(6)) timestamp
            builder.Content <- $"{shieldId} shield is already in use. Wait {cooldown} minutes to use this shield again"
            do! event.Interaction.CreateFollowupMessageAsync(builder)
                |> Async.AwaitTask
                |> Async.Ignore
            do! DbService.updatePlayer <| { player with Actions = updatedDefenses }
    })

let handleButtonEvent (_ : DiscordClient) (event : ComponentInteractionCreateEventArgs) =
    match event.Id with
    | id when id.StartsWith("Attack")  -> handleAttack event
    | id when id.StartsWith("Defend")  -> handleDefense event
    | id when id.StartsWith("Trainer") -> Trainer.handleButtonEvent event |> Async.StartAsTask :> Task
    | _ ->
        task {
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            builder.Content <- $"Incorrect Action identifier {event.Id}"
            do! event.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                |> Async.AwaitTask
        }

type HackerGame() =
    inherit ApplicationCommandModule ()

    [<SlashCommand("hack", "Send a hack attack to another player")>]
    member this.AttackCommand (ctx : InteractionContext, [<Option("target", "The player you want to hack")>] target : DiscordUser) =
        if ctx.Channel.Id = GuildEnvironment.channelTraining then
            Trainer.attack ctx target
        else
            attack ctx target

    [<SlashCommand("shield", "Create a passive shield that will protect you for a certain time")>]
    member this.ShieldCommand (ctx : InteractionContext) =
        if ctx.Channel.Id = GuildEnvironment.channelTraining then
            Trainer.defend ctx
        else
            defend ctx

//    [<SlashCommand("test-autocomplete", "Create a passive defense that will last 24 hours")>]
    member this.TestAutoComplete (ctx : InteractionContext) =
        async {
            let builder = DiscordInteractionResponseBuilder()
            builder.IsEphemeral <- true
            do! ctx.Interaction.CreateResponseAsync(InteractionResponseType.ChannelMessageWithSource, builder)
                |> Async.AwaitTask
        } |> Async.StartAsTask
          :> Task