Joseph Ferano
26c53e0a19
The mechanical half, ahead of the parser change that needs it. tools/unit-return.py
fills the empty slot with () and rewrites Unit as () wherever a type is spelled --
(Fn [i32] Unit), (Map i32 Unit), a return type written out.
Deciding whether a defn already had a return type is the whole difficulty, and
the script does it the way parse.ml did: is_type_form is transcribed rather than
improved, because being identical to the parser it replaces is what makes the
sweep meaning-preserving. It is re-runnable, so the lanes that branched before
this can have the same pass at merge:
python3 tools/unit-return.py .
python3 tools/unit-return.py --in-strings test/test_flan.ml test/test_acceptance.ml \
test/test_session.ml emacs/test-flan-dev.el emacs/test-flan-mode.el
python3 tools/unit-return.py --raw-ml lib/prelude.ml
python3 tools/unit-return.py --in-html web/index.html
-v logs every defn it saw and what it decided, which is how a sweep of 440 sites
gets reviewed at all. Embedded modes pool a file's type declarations across all
its fragments, because a snippet split across concatenation -- decls ^ "(defn f
[s [u8]] Cursor ...)" -- cannot see the names the other half declared; pooled
names count only in bare-symbol position, for the same reason the prelude's do.
A fragment that cuts off mid-form is skipped rather than guessed at. Five sites
in test_flan.ml still needed a hand, and they are in this commit.
Two things ride along because the sweep needs them: parse.ml reads a lone () as
the return type of a function with no body, which was not a shape the old
optional slot could produce; and the map refusals name () rather than Unit, since
that is now the spelling a caller wrote.
46 lines
1.7 KiB
Plaintext
46 lines
1.7 KiB
Plaintext
;;;; handler-bind and signal — spec-conditions.md §1 and §2.
|
|
;;;;
|
|
;;;; The accumulation case, which is what makes these two worth having on their
|
|
;;;; own: signal returns Unit, a handler that returns normally leaves the
|
|
;;;; signalling function to carry on, and with nothing matching signal is a
|
|
;;;; no-op. No control flow is altered, so none of the transfer machinery
|
|
;;;; restart-case needs exists yet.
|
|
(defstruct AssetMissing [id i32])
|
|
(defstruct Corrupt [id i32])
|
|
|
|
(defvar seen i64)
|
|
(defvar other i64)
|
|
|
|
;;; Signals twice and keeps going both times — that is the whole of §1.
|
|
(defn load-all [] ()
|
|
(signal (AssetMissing {.id 1}))
|
|
(signal (AssetMissing {.id 2}))
|
|
(signal (Corrupt {.id 3})))
|
|
|
|
(defn main [] i32
|
|
;; No handler: a no-op, not an abort and not a message (§2).
|
|
(load-all)
|
|
(print seen) (println "") ; 0
|
|
|
|
(handler-bind [(AssetMissing [c] (set seen (+ seen (i64 (.id c)))))]
|
|
(load-all))
|
|
(print seen) (println "") ; 1 + 2 = 3
|
|
|
|
;; Two clauses, and only the matching one runs for each condition.
|
|
(handler-bind [(AssetMissing [c] (set seen (+ seen 10)))
|
|
(Corrupt [c] (set other (+ other (i64 (.id c)))))]
|
|
(load-all))
|
|
(print seen) (println "") ; 3 + 20 = 23
|
|
(print other) (println "") ; 3
|
|
|
|
;; Nesting: the inner frame does not displace the outer one, so both run.
|
|
(handler-bind [(Corrupt [c] (set other (+ other 100)))]
|
|
(handler-bind [(Corrupt [c] (set other (+ other 1000)))]
|
|
(signal (Corrupt {.id 0}))))
|
|
(print other) (println "") ; 3 + 1000 + 100 = 1103
|
|
|
|
;; And the stack is back to what it was: no handler, no effect.
|
|
(load-all)
|
|
(print other) (println "") ; 1103
|
|
0)
|